First Person Camera
Beispielscript mit 3 Loops
- 0159: set_camera_on_ped $PLAYER_ACTOR mit den Parametern 45 2 wurde von CeeJ entdeckt
- und simuliert eigentlich nur eine First Person-Ansicht
- Es funktioniert nicht, wenn der Code ausgeführt wird, während der Player sich in einem Fahrzeug befindet
- Aber es funktioniert, wenn der Player in ein Fahrzeug einsteigt nachdem der Code ausgeführt wurde
- Außerdem kommt es zu Fehldarstellungen beim Aufschalten der Waffen: RocketLauncher, Headseek und Sniper
- Nach passierter key_pressed-Abfrage macht es Sinn, einen wait-code
von 1 Sekunde folgen zu lassen,
- da sonst die key_pressed-Abfrage im Loop zu schnell wiederholt wird
{$CLEO .cs}
:FirstPcam
03A4: name_thread "FPV"
wait 1000
:FirstPcam_1//---------------1. LoopAdress
0001: wait 0 ms
if
0256: player $PLAYER_CHAR defined
004D: jump_if_false @FirstPcam_1
if
00E1: key_pressed 0 13//---------key = CAMERA_CHANGE_VIEW_ALL_SITUATIONS
004D: jump_if_false @FirstPcam_1
if
80DF: not actor $PLAYER_ACTOR driving
004D: jump_if_false @FirstPcam_15
0159: set_camera_on_ped $PLAYER_ACTOR 45 2
wait 1000
:FirstPcam_2//---------------2. LoopAdress
0001: wait 0 ms
if
0256: player $PLAYER_CHAR defined
004D: jump_if_false @FirstPcam_2
if
80DF: not actor $PLAYER_ACTOR driving
004D: jump_if_false @FirstPcam_15
if
00E1: key_pressed 0 13//---------key = CAMERA_CHANGE_VIEW_ALL_SITUATIONS
004D: jump_if_false @FirstPcam_5
02EB: restore_camera_with_jumpcut
0925: restore_camera_to_user_defined
wait 1000
0002: jump @FirstPcam_1
:FirstPcam_5
if
00E1: key_pressed 0 6//----------------key = PED_LOCK_TARGET (aiming)
004D: jump_if_false @FirstPcam_2
if or
02D8: actor $PLAYER_ACTOR currentweapon == 34
02D8: actor $PLAYER_ACTOR currentweapon == 36
02D8: actor $PLAYER_ACTOR currentweapon == 43
004D: jump_if_false @FirstPcam_2
02EB: restore_camera_with_jumpcut
0925: restore_camera_to_user_defined
:FirstPcam_9//---------------3. LoopAdress
0001: wait 0 ms
if
0256: player $PLAYER_CHAR defined
004D: jump_if_false @FirstPcam_13
if
80E1: not key_pressed 0 6//----------------key = PED_LOCK_TARGET (aiming)
004D: jump_if_false @FirstPcam_9
0159: set_camera_on_ped $PLAYER_ACTOR 45 2
0002: jump @FirstPcam_2
:FirstPcam_13
02EB: restore_camera_with_jumpcut
0925: restore_camera_to_user_defined
0002: jump @FirstPcam_1
:FirstPcam_15
09AD: vehicle_camera_mode 0
0001: wait 1000 ms
0002: jump @FirstPcam_1
